Excel VBA 質問スレッド No.823 (未解決)

【緊急】VBAでパワーポイント内の埋め込みグラフのデータを転記したい

投稿者 : フジ     投稿日時 : 2022/06/23(Thu) 04:39:43     OS : Windows 8     EXCEL : Excel 2016
初めて投稿します。よろしくお願いします。
VBAで埋め込みグラフのデータを転記したいのですが、
グラフを開くところまでは出来たのですが、データの選択が出来ていません。
「Microsoft PowerPoint内のグラフ」のデータを選択する方法をご存知の方
すみませんが、教えて頂きたいので、よろしくお願いします。

[返信 1] Re : 【緊急】VBAでパワーポイント内の埋め込みグラフのデータを転記したい
投稿者 : tok     投稿日時 : 2022/06/23(Thu) 14:00:28
もし、動作しないなら、グラフを開くところまでのコードを提示下さい。
Sub Excelでpptグラフデータ取得()
Const PPT = "グラフ.pptx" 'chartがあるpptファイル

Dim pptPath As String
Dim ppApp As Object, ppPrs As Object
Dim cht, sld, shp, r

pptPath = ThisWorkbook.Path & "\" 'このexcelブックと同じフォルダ(ブックは一旦保存すること)

Set ppApp = CreateObject("PowerPoint.Application")
On Error Resume Next
Set ppPrs = ppApp.Presentations(PPT)
On Error GoTo 0
If ppPrs Is Nothing Then
Set ppPrs = ppApp.Presentations.Open(pptPath & PPT)
End If

'グラフを見つける
Set cht = Nothing
For Each sld In ppPrs.slides
For Each shp In sld.Shapes
On Error Resume Next
Set cht = shp.Chart
On Error GoTo 0
If Not cht Is Nothing Then Exit For
Next
If Not cht Is Nothing Then Exit For
Next
If cht Is Nothing Then
MsgBox "グラフ無し"
Exit Sub
Else
ppPrs.Windows(1).Activate
ppApp.CommandBars.ExecuteMso "ChartShowDataContextualMenu" 'excelでデータを編集
With Workbooks(Workbooks.Count)
.Worksheets(1).UsedRange.Copy
.Close False
End With
End If
Range("a5").PasteSpecial
Set ppPrs = Nothing: Set ppApp = Nothing
End Sub

[返信 2] Re : 【緊急】VBAでパワーポイント内の埋め込みグラフのデータを転記したい
投稿者 : tok     投稿日時 : 2022/06/23(Thu) 18:42:06
ゥワー怖い痴呆症が出てきているようです。

> ppPrs.Windows(1).Activate
shp.Select '追加
cht.Select '追加
> ppApp.CommandBars.ExecuteMso "ChartShowDataContextualMenu" 'excelでデータを編集

[返信 3] Re : 【緊急】VBAでパワーポイント内の埋め込みグラフのデータを転記したい
投稿者 : フジ     投稿日時 : 2022/06/24(Fri) 04:43:25
tok様 返信ありがとうございます。
早速今日やってみようと思います。
これで開けば埋め込みグラフの中の数値データにアクセス出来るということですよね。
クリックしてもセル名の表示もされないし、マクロの記録も出来ないので諦めかけていましたが、
出来そうということが分かっただけでも、まずはありがたいです。
実施後、また連絡しますが、お礼まで。

当掲示板について
返信入力フォーム
お 名 前  :
内  容   :
ステータス  : この質問を解決済みにする

認証コード  :
        キャプチャ画像


( 処理日時 : 2022-07-07 13:57:26 )

Page
Top