アクセス上位ページ
 
最近の更新内容
(6)-a.セルとレンジ ⇐ [PREV]
[NEXT] ⇒ (6)-c.数式の設定

Excel VBA ≫ 1.基礎編 - セル・レンジ(6)-b.行と列、その他範囲指定方法

行と列

行と列によってセル範囲を指定する方法を説明します。


行・列単位で指定する方法

RowsColumnsを使用すると行・列単位で範囲を指定できます。 複数の行・列を指定する場合はダブルクォーテーションとコロン(:)を使用します。

また、RowsにつづけてRowHeight、ColumnsにつづけてColumnWidthを指定することで行の高さや、列の幅を変更できます。



Sub sample6_5()
    '単一行を指定
    With Rows(3)
        .Interior.Color = vbBlue
        '行の高さを2倍にします。
        .RowHeight = .RowHeight * 2
    End With

    '複数行を指定
    Rows("5:7").Interior.Color = vbBlue

    '単一列を指定
    Columns(3).Interior.Color = vbGreen

    '複数列を指定
    With Columns("E:G")
        .Interior.Color = vbGreen
        '列の幅を1/2にします。
        .ColumnWidth = .ColumnWidth / 2
    End With
End Sub
⇒ サンプルマクロ集 へ

<実行結果> sample6_5の実行結果

あるセルを含む行・列で指定する方法

あるセルまたはレンジにおいてEntireRowEntireColumnを使用すると、そのセルやレンジを含む行・列を指定することができます。

Sub sample6_6()
    With Range("B2,D4:E5")
        .Value = "テスト"
        .EntireRow.Interior.Color = vbBlue
        .EntireColumn.Interior.Color = vbGreen
    End With
End Sub
⇒ サンプルマクロ集 へ

<実行結果> sample6_6の実行結果

その他の範囲指定方法

基準セルからのオフセット

あるセルまたはレンジにおいてOffsetプロパティを使用すると、 そのセルやレンジを基準として指定量移動させたセルを選択することができます。 Offsetには行方向、列方向の移動量(マイナスも可能)をそれぞれ引数として指定します。

Sub sample6_7()
    With Range("B2,D4:E5")
        .Value = "基準"
        .Interior.Color = vbGreen

        With .Offset(5, 2)
            .Value = "変更後"
            .Interior.Color = vbYellow
        End With
    End With
End Sub
⇒ サンプルマクロ集 へ

<実行結果> sample6_7の実行結果
<サイト内関連リンク> 関連リンクもチェック!!
- Offsetの使用例(sample6_21)

空白行と空白列で囲まれた領域

CurrentRegionはある基準となるセルが含まれる空白行と空白列で囲まれた矩形領域を選択します。 表などの矩形領域を選択するときに使用します。

Sub sample6_8()
    Range("B3").CurrentRegion.Interior.Color = vbGreen
End Sub
⇒ サンプルマクロ集 へ

<実行前> sample6_8実行前 <実行後> sample6_8実行後
<サイト内関連リンク> 関連リンクもチェック!!
- ワークシート内の使用済み領域(UsedRange)
カテゴリ内ページ



Page
Top