アクセス上位ページ
 
最近の更新内容
(6)-e.セルの書式(配置) ⇐ [PREV]
[NEXT] ⇒ (6)-g.フォントの部分設定

Excel VBA ≫ 1.基礎編 - セル・レンジ(6)-f.セルの書式(フォント)

セルの書式(フォント)

セルの書式設定画面のフォントタブに対応するプロパティについて説明します。

    セルの書式設定画面のフォントタブ



  • フォントに関するプロパティの設定例
  • Sub sample6_15()
        With Range("A1").Font
            'フォント名
            .Name = "MS Pゴシック"
            'フォントスタイル
            .FontStyle = "標準"
            'サイズ
            .Size = 12
            '下線
            .Underline = xlUnderlineStyleSingle
            'フォント色
            .Color = vbRed
            '取消線
            .Strikethrough = False
            '上付き
            .Superscript = False
            '下付き
            .Subscript = False
        End With
    End Sub
    
    ⇒ サンプルマクロ集 へ


フォント名、サイズ

  • フォント名 - Font.Name
  • "MS Pゴシック" や "MS P明朝" などのフォント名を設定
  • サイズ - Font.Size
  • 文字サイズをポイント単位で整数値を設定


フォントスタイル - Font.Style プロパティ

フォントスタイルに設定可能な定数
フォントスタイルはFont.Styleプロパティに下表の定数を設定することで変更することができます。
ただ、Font.StyleはFont.BoldおよびFont.Italicで代用できますので、使いやすい方を選ぶとよいでしょう。

プロパティ 定数 説明
Font.Style "標準"(または値をクリア) 標準
"斜体" または "Italic" 斜体
"太字" または "Bold" 太字
"太字 斜体" または
"Bold Italic"
太字+斜体
※間の空白は半角

  • フォントスタイルを"太字 斜体"にする3つの設定例
  • Sub sample6_16()
        With Range("A1")
            .Value = "FontStyleに「太字 斜体」を設定した場合"
            .Font.FontStyle = "太字 斜体"
        End With
    
        With Range("A3")
            .Value = "FontStyleに「Bold Italic」を設定した場合"
            .Font.FontStyle = "Bold Italic"
        End With
    
        With Range("A5")
            .Value = "Bold、ItalicにTrueを設定した場合"
            .Font.Bold = True
            .Font.Italic = True
        End With
    End Sub
    
    ⇒ サンプルマクロ集 へ

    <実行結果> sample6_16の実行結果

下線 - Font.Underline プロパティ

下線に設定可能な定数
下線はFont.Underlineプロパティに下表の定数を設定することで変更することができます。

プロパティ 定数 説明
Font.Underline xlNone または
xlUnderlineStyleNone
なし
xlUnderlineStyleSingle 下線
xlUnderlineStyleDouble 二重下線
xlUnderlineStyleSingleAccounting 下線(会計)
xlUnderlineStyleDoubleAccounting 二重下線(会計)

  • 下線の設定例
  • Sub sample6_17()
        With Range("A1")
            .Value = "下線 AaAaあぁアァ亜宇"
            .Font.Underline = xlUnderlineStyleSingle
        End With
    
        With Range("A3")
            .Value = "二重下線 AaAaあぁアァ亜宇"
            .Font.Underline = xlUnderlineStyleDouble
        End With
    
        With Range("A5")
            .Value = "下線(会計) AaAaあぁアァ亜宇"
            .Font.Underline = xlUnderlineStyleSingleAccounting
        End With
    
        With Range("A7")
            .Value = "二重下線(会計) AaAaあぁアァ亜宇"
            .Font.Underline = xlUnderlineStyleDoubleAccounting
        End With
    End Sub
    

    <実行結果> sample6_17の実行結果

フォント色 - Font.Color Font.ColorIndex プロパティ

カラーパレット
フォント色はFont.ColorまたはFont.ColorIndexプロパティのどちらかを設定します。 それぞれ色の指定の仕方が異なりますので、扱いやすい方を使用しましょう。
  • Font.Color
  • ・・・ 色定数またはRGB値で色を指定
  • Font.ColorIndex
  • ・・・ カラーパレットのインデックス値で色を指定
    ※フォント色を自動設定する場合は定数を指定

プロパティ 定数・値 説明
Font.Color vbBlack 黒色
vbRed 赤色
vbGreen 緑色
vbBlue 青色
vbYellow 黄色
vbMagenta マゼンタ
vbCyan シアン
vbWhite 白色
RGB関数の戻り値
※R,G,Bは0〜255の範囲
RGB値(Long型)
Font.ColorIndex xlAutomatic または
xlColorIndexAutomatic
自動設定
※上図の"自動"に相当
1〜56の整数値 カラーパレットの
インデックス値
※上図の色配置とは別物
カラーパレットの一覧


取消線、上付き文字、下付き文字

取消線はFont.StrikethroughプロパティにTrueを設定することで可能になります。
上付き文字はFont.SuperscriptプロパティにTrueを設定することで可能になります。
下付き文字はFont.SubscriptプロパティにTrueを設定することで可能になります。
上付き文字と下付き文字は同時に設定することはできません。

  • 取消線、上付き文字、下付き文字の設定例
  • Sub sample6_18()
        With Range("A1")
            .Value = "取消線 AaAaあぁアァ亜宇"
            .Font.Strikethrough = True
        End With
    
        With Range("A3")
            .Value = "216 = 65536です。"
            '16(2文字目から2文字分)を上付き文字にします。
            .Characters(2, 2).Font.Superscript = True
        End With
    
        With Range("A5")
            .Value = "水の化学式はH2Oです。"
            '2(8文字目から1文字分)を下付き文字にします。
            .Characters(8, 1).Font.Subscript = True
        End With
    End Sub
    

    <実行結果> sample6_18の実行結果
カテゴリ内ページ



Page
Top