アクセス上位ページ
 
最近の更新内容

Excel VBA ≫ 1.基礎編 - ワークシート(7)-c.ワークシートの追加

ワークシートの追加 - Add メソッド

ワークシートを追加するには Worksheets コレクションの Add メソッドを使用します。 ワークシートを挿入する位置は Before または After のどちらかの引数で指定することができます。 引数 Before および After を両方省略すると一番左端にシートが追加されます。



  • 【構文】
    Worksheets.Add ( [Before] [, After] [, Count] [, Type] )

  • 引数名 省略 定数/データ型 説明
    Before Variant型
    (シートオブジェクト)
    指定したシートオブジェクトの直前に、新しいシートを追加します。
    After Variant型
    (シートオブジェクト)
    指定したシートオブジェクトの直後に、新しいシートを追加します。
    Count Variant型 追加するシートの数を指定します。 既定値は 1 です。
    Type xlChart グラフシート
    xlDialogSheet ダイアログシート
    xlExcel4IntlMacroSheet Excel バージョン 4
    International Macro シート
    xlExcel4MacroSheet Excel バージョン 4
    マクロ シート
    xlWorksheet ワークシート(既定値



  • Add メソッドの使用例1
  • アクティブワークブックへワークシートを追加する例です。 引数 After, Count を指定して左から2番目にワークシートを2枚追加しています。

    ※引数をすべて省略すると一番左端にシートが1枚だけ追加されます。
    Sub sample_eb073_01()
    
        '左から2番目にシートを2枚追加
        Worksheets.Add After:=Worksheets(1), Count:=2
    
    End Sub
    
    ⇒ サンプルマクロ集 へ

    <アクティブワークブック内のシート> アクティブワークブック内のシート <実行結果> sample_eb073_01実行後

管理人から一言・・・ ThisWorkbook
ワークブックの指定を省略すると処理時点でアクティブになっている(最前面に表示されている)ブックが処理の対象となります。もし、処理の対象を実行したマクロが組み込まれているブックに限定したい場合はシートのまえに"ThisWorkbook"をつけてください。

(例)ThisWorkbook.Worksheets.Add

  • Add メソッドの使用例2
  • 一番右端へワークシートを追加し、シート名やフォントなどのプロパティを変更する例です。
    Sub sample_eb073_02()
        Dim mySheet     As Worksheet
    
        'シートを追加し、その追加したシートの参照を変数へ設定
        Set mySheet = Worksheets.Add _
                      (After:=Worksheets(Worksheets.Count))
    
        With mySheet
            .Name = "DDD"   '追加したシートの名前を変更
    
            'セルのフォント名とフォントサイズを変更
            With .Cells.Font
                .Name = "MS ゴシック"
                .Size = 9
            End With
    
            .Range("A1").Value = "テスト"
        End With
    End Sub
    

    <アクティブワークブック内のシート> アクティブワークブック内のシート <実行結果> sample_eb073_02実行後のシート セルのフォント名、フォントサイズも変更されてます。 sample_eb073_02実行後のセル書式
  • 参考
  • sample_eb073_02 では追加したシートの参照を変数 mySheet へ一旦保存しましたが、 この変数を使用せず以下のように記述することができます。 できるだけ変数の数を少なくしたい場合はこの方法で記述するとよいでしょう。
    Sub sample_eb073_03()
        'シートの追加とプロパティの変更
        With Worksheets.Add(After:=Worksheets(Worksheets.Count))
            .Name = "DDD"   '追加したシートの名前を変更
    
            'セルのフォント名とフォントサイズを変更
            With .Cells.Font
                .Name = "MS ゴシック"
                .Size = 9
            End With
    
            .Range("A1").Value = "テスト"
        End With
    End Sub
    

<サイト内関連リンク> 関連リンクもチェック!!
- ワークシートの削除( Delete メソッド)
カテゴリ内ページ



Page
Top