アクセス上位ページ
 
最近の更新内容
(7)-o.PrintOut メソッド ⇐ [PREV]
[NEXT] ⇒ (8).ワークブック

Excel VBA ≫ 1.基礎編 - ワークシート(7)-p.印刷ヘッダー、フッターの設定

印刷ヘッダー、フッターの設定

印刷ヘッダー、フッターはそれぞれ左、中央、右の3か所に設定でき、 フォントやフォントサイズ、字体など細かく指定することができます。 また、独自の変数により日付や時刻、ブック名やシート名などを表示することもできます。



  • 印刷ヘッダー、フッターの設定例1
  • Sub sample_eb07g_01()
        With ActiveSheet
            'ヘッダーの設定
            .PageSetup.LeftHeader = "左ヘッダー"
            '太字、20pt
            .PageSetup.CenterHeader = "&B&20中央ヘッダー"
            .PageSetup.RightHeader = "右ヘッダー"
    
            'フッターの設定
            .PageSetup.LeftFooter = "左フッター"
            .PageSetup.CenterFooter = "中央フッター "
            .PageSetup.RightFooter = "右フッター"
    
            '印刷プレビュー表示
            .PrintPreview
        End With
    End Sub
    
    ⇒ サンプルマクロ集 へ

    印刷ヘッダー、フッターの設定例

    印刷ヘッダー、フッターに設定可能な書式コード
    書式コード 説明
    &L このコードに続く文字列を左詰めに配置します。
    &C このコードに続く文字列を中央揃えに配置します。
    &R このコードに続く文字列を右詰めに配置します。
    &E 文字列を二重下線付きで印刷します。
    &X 上付き文字を印刷します。
    &Y 下付き文字を印刷します。
    &B 文字列を太字で印刷します。
    &I 文字列を斜体で印刷します。
    &U 文字列を下線付きで印刷します。
    &S 文字列を取り消し線付きで印刷します。
    &"フォント名" 指定したフォントで文字を印刷します。
    フォント名は、必ず半角の二重引用符 (") で囲んでください。
    &nn 指定したフォント サイズで文字を印刷します。
    nn には、ポイント数を表す 2 桁の数値を指定します。
    &color 文字を指定された色で印刷します。
    16進数の色の値を指定します。


    印刷ヘッダー、フッターに設定可能なVBAコード
    VBAコード 説明
    &D 現在の日付を印刷します。
    &T 現在の時刻を印刷します。
    &F ファイルの名前を印刷します。
    &A シート見出し名を印刷します。
    &P ページ番号を印刷します。
    &P+<数値> ページ番号に指定した <数値> を加えた値を印刷します。
    &P-<数値> ページ番号から指定した <数値> を引いた値を印刷します。
    && アンパサンド (&) を 1 つ印刷します。
    &N ファイルのすべてのページ数を印刷します。
    &Z ファイル パスを印刷します。
    &G イメージを挿入します。



  • 印刷ヘッダー、フッターの設定例2
  • 中央ヘッダーに複数のフォント、フォントサイズを設定する例です。
    Sub sample_eb07g_02()
        With ActiveSheet
            '太字斜体明朝20pt+シート名、注釈は標準11pt
            .PageSetup.CenterHeader = _
                "&B&I&""MS P明朝""&20&A 年間売上一覧表  " & _
                "&""-,標準""&11※関東地区のみ"
    
            '印刷プレビュー表示
            .PrintPreview
        End With
    End Sub
    
    ⇒ サンプルマクロ集 へ

    <sample_eb07g_02 実行後>
    sample_eb07g_02 実行後

  • 印刷ヘッダー、フッターの設定例3
  • 右ヘッダーに日付と時刻を設定する例です。
    Sub sample_eb07g_03()
        With ActiveSheet
            '日付、時刻を設定
            .PageSetup.RightHeader = "印刷日時 : &D &T"
    
            '印刷プレビュー表示
            .PrintPreview
        End With
    End Sub
    
    ⇒ サンプルマクロ集 へ

    <sample_eb07g_03 実行後>
    sample_eb07g_03 実行後

  • 印刷ヘッダー、フッターの設定例4
  • 中央フッターに現在ページと総ページ数を設定する例です。
    Sub sample_eb07g_04()
        With ActiveSheet
            '現在ページと総ページ数
            .PageSetup.CenterFooter = "&P / &N"
    
            '印刷プレビュー表示
            .PrintPreview
        End With
    End Sub
    
    ⇒ サンプルマクロ集 へ

    <sample_eb07g_04 実行後>
    sample_eb07g_04 実行後


<サイト内関連リンク> 関連リンクもチェック!!
- PrintPreview メソッド
- PrintOut メソッド
カテゴリ内ページ



Page
Top