アクセス上位ページ
 
最近の更新内容
(8)-f.Activate メソッド ⇐ [PREV]
[NEXT] ⇒ (8)-h.Save、SaveAs メソッド

Excel VBA ≫ 1.基礎編 - ワークブック(8)-g.Close メソッド

Close メソッド

ワークブックを閉じるときは Close メソッドを使用します。 変更があった場合に変更内容を保存するかどうかや、変更後のファイル名は引数で指定することができます。



  • 【構文】
    object.Close ( [SaveChanges] [, Filename] [, RouteWorkbook] )
  • ※objectはworkbookオブジェクトを表す変数


    引数名 省略 データ型
    定数
    説明
    SaveChanges True / False True を指定すると、変更がブックに保存されます。 ブックにファイル名が付けられていない場合は、FileName がファイル名として使用されます。 Filename を省略すると、ファイル名を指定するダイアログ ボックスがユーザーに表示されます。
    Filename バリアント型
    (Variant)
    変更後のブックのファイル名を指定します。
    RouteWorkbook True / False ブックを次の受信者に回覧する必要がない場合、この引数は無視されます。 ブックを次の受信者に回覧する必要がある場合に True を指定すると、次の受信者にブックが送信されます。 False を指定すると、ブックは送信されません。 この引数を省略すると、ブックを送信するかどうかを確認するダイアログ ボックスがユーザーに表示されます。


  • Close メソッドの使用例1
  • ワークブック"test.xlsx"を保存せずに閉じる例です。
    Sub sample_eb087_01()
        With Workbooks("test.xlsx")
            .Worksheets(1).Range("A1").Value = "test1"
    
            '保存せずに閉じます。
            .Close False
        End With
    End Sub
    
    ⇒ サンプルマクロ集 へ


  • Close メソッドの使用例2
  • ワークブック"test.xlsx"を保存してから閉じる例です。
    Sub sample_eb087_02()
        With Workbooks("test.xlsx")
            .Worksheets(1).Range("A1").Value = "test2"
    
            '開いたときと同じファイル名で保存して閉じます。
            .Close True
        End With
    End Sub
    
    ⇒ サンプルマクロ集 へ


  • Close メソッドの使用例3
  • ワークブック"test.xlsx"を別名"test_BACKUP.xlsx"で保存してから閉じる例です。
    Sub sample_eb087_03()
        Dim pos             As Integer
        Dim NewFilename     As String
    
        With Workbooks("test.xlsx")
            .Worksheets(1).Range("A1").Value = "test3"
    
            'ファイルパスの後ろからファイル拡張子の"."を探します。
            pos = InStrRev(.Name, ".")
    
            'ワークブック名に"_BACKUP"を付与します。
            NewFilename = .Path & "\" & Left(.Name, pos - 1) & _
                          "_BACKUP" & Mid(.Name, pos)
    
            '別名で保存して閉じます。
            .Close SaveChanges:=True, _
                   Filename:=NewFilename
        End With
    End Sub
    

    <sample_eb087_03 実行結果> 別名で保存された様子

管理人から一言・・・ 引数 Filename はフルパスを指定
引数 Filename にファイル名のみを指定するとカレントフォルダに保存されます。カレントフォルダは『ファイルを開く』操作などにより変わってしまうので、引数 Filename にはフルパスを指定しておくのが無難です。
カテゴリ内ページ



Page
Top