アクセス上位ページ
 
最近の更新内容
(1)-d.FileDialogオブジェクト@ ⇐ [PREV]
[NEXT] ⇒ (1)-f.FileDialogオブジェクトB

Excel VBA ≫ 2.関数リファレンス - 組み込みダイアログ(1)-e.FileDialogオブジェクトA

ファイルダイアログオブジェクトの使用例(その1)

このページと次のページでは前のページ(ファイルダイアログオブジェクトについて)で解説した ファイルダイアログオブジェクトの4つのタイプについて具体的な使用例をそれぞれ挙げていきます。 (当ページでは4つのうちの2つについて使用例を挙げます。)

ファイルダイアログオブジェクトにはある程度決まった使い方がありますので、それをしっかり覚えておきましょう。



  • 『ファイルを選択する』(msoFileDialogFilePicker)使用例
  • 『フォルダを選択する』(soFileDialogFolderPicker)使用例


  • 以下の使用例で扱うサンプルフォルダとその中身
  • フォルダパス ・・・ C:¥Users¥Guest¥test サンプルフォルダとその中身
  • 『ファイルを選択する』(msoFileDialogFilePicker)使用例
  • ファイルダイアログオブジェクトでファイルを選択する例です。 この例では、複数ファイルの選択を可能にし、ファイルフィルタと初期表示フォルダの設定を行っています。 ファイルを選択して [ OK ] ボタンを押すと、選択したファイルパスの一覧をメッセージボックスに表示します。

    Sub sample_ef014_01()
        Dim strFiles    As String
        Dim i           As Integer
    
        With Application.FileDialog(msoFileDialogFilePicker)
            'ファイルの複数選択を可能にする
            .AllowMultiSelect = True
            'ファイルフィルタのクリア
            .Filters.Clear
            'ファイルフィルタの追加
            .Filters.Add "エクセルブック", "*.xls*"
            .Filters.Add "その他", "*.txt; *.doc*"
            '初期表示フォルダの設定
            .InitialFileName = "C:\Users\Guest\test\"
    
            If .Show = -1 Then  'ファイルダイアログ表示
                ' [ OK ] ボタンが押された場合
                For i = 1 To .SelectedItems.Count
                    strFiles = strFiles & vbLf & .SelectedItems(i)
                Next i
    
                MsgBox "以下のファイルが選択されました。" & _
                        vbLf & strFiles, vbInformation
            Else
                ' [ キャンセル ] ボタンが押された場合
                MsgBox "ファイル選択がキャンセルされました。", vbExclamation
            End If
        End With
    
    End Sub
    
    ⇒ サンプルマクロ集 へ

    • ファイルダイアログの初期表示画面
    • 最初のファイルフィルタにエクセルの拡張子(*.xls*)を設定したため、初期表示画面にはエクセルブックのみ表示されます。 ファイルダイアログの初期表示画面
    • ファイルフィルタリストの内容
    • ファイルフィルタリストの内容
    • 複数のファイルを選択
    • 複数のファイルを選択するには Shift または Ctrl キーを押した状態でファイルをクリックします。 この例では Ctrl キーを押した状態でファイルをクリックしています。 複数のファイルを選択
    • [ OK ] ボタンを押した場合
    •  [ OK ] ボタン押下
    • [ キャンセル ] ボタンまたは右上の [ × ] を押した場合
    •  [ キャンセル ] ボタン押下

  • 『フォルダを選択する』(soFileDialogFolderPicker)使用例
  • ファイルダイアログオブジェクトでフォルダを選択する例です。 フォルダ選択のため、AllowMultiSelect プロパティや Filters プロパティの設定は不要です。 ファイルを選択して [ OK ] ボタンを押すと、選択したフォルダパスをメッセージボックスに表示します。

    Sub sample_ef014_02()
    
        With Application.FileDialog(msoFileDialogFolderPicker)
            '初期表示フォルダの設定
            .InitialFileName = "C:\Users\Guest\test\"
    
            If .Show = -1 Then  'ファイルダイアログ表示
                ' [ OK ] ボタンが押された場合
                MsgBox "以下のフォルダが選択されました。" & _
                        vbLf & .SelectedItems(1), vbInformation
            Else
                ' [ キャンセル ] ボタンが押された場合
                MsgBox "フォルダ選択がキャンセルされました。", vbExclamation
            End If
        End With
    
    End Sub
    

    • ファイルダイアログの初期表示画面
    • ファイルダイアログの初期表示画面
    • フォルダを選択
    • フォルダを選択
    • [ OK ] ボタンを押した場合
    •  [ OK ] ボタン押下
    • [ キャンセル ] ボタンまたは右上の [ × ] を押した場合
    •  [ キャンセル ] ボタン押下

カテゴリ内ページ
Excel VBA 〜 総目次 〜
- 2.関数リファレンス
--- (1)-a.InputBox関数
--- (1)-b.InputBoxメソッド
--- (1)-c.MsgBox関数
--- (1)-d.FileDialogオブジェクト@
--- (1)-e.FileDialogオブジェクトA
--- (1)-f.FileDialogオブジェクトB



Page
Top