アクセス上位ページ
 
最近の更新内容
(1)-e.FileDialogオブジェクトA ⇐ [PREV]
[NEXT] ⇒ (2).文字列操作

Excel VBA ≫ 2.関数リファレンス - 組み込みダイアログ(1)-f.FileDialogオブジェクトB

ファイルダイアログオブジェクトの使用例(その2)

前のページに引き続き、 ファイルダイアログオブジェクトの残り2つのタイプについて具体的な使用例をそれぞれ挙げていきます。
  • 『ファイルを開く』(msoFileDialogOpen)使用例
  • 『ファイルを保存する』(msoFileDialogSaveAs)使用例




  • 以下の使用例で扱うサンプルフォルダとその中身
  • フォルダパス ・・・ C:¥Users¥Guest¥test サンプルフォルダとその中身
  • 『ファイルを開く』(msoFileDialogOpen)使用例
  • ファイルダイアログオブジェクトでファイルを開く例です。 この例では、複数ファイルの選択を可能にし、ファイルフィルタと初期表示フォルダの設定を行っています。 ファイルを選択して [ OK ] ボタンを押すと、選択したファイルを開いた後、ファイルパスの一覧をメッセージボックスに表示します。
    『ファイルを開く』はエクセル以外のファイルも開くことはできますが、拡張子にかかわらずすべてエクセルで開いてしまいます。
    Sub sample_ef014_03()
        Dim strFiles    As String
        Dim i           As Integer
    
        With Application.FileDialog(msoFileDialogOpen)
            'ファイルの複数選択を可能にする
            .AllowMultiSelect = True
            'ファイルフィルタのクリア
            .Filters.Clear
            'ファイルフィルタの追加
            .Filters.Add "エクセルブック", "*.xls*"
            '初期表示フォルダの設定
            .InitialFileName = "C:\Users\Guest\test\"
    
            If .Show = -1 Then  'ファイルダイアログ表示
                ' [ OK ] ボタンが押された場合
                'ファイルオープン実行
                .Execute
    
                For i = 1 To .SelectedItems.Count
                    strFiles = strFiles & vbLf & .SelectedItems(i)
                Next i
    
                MsgBox "以下のファイルを開きました。" & _
                        vbLf & strFiles, vbInformation
            Else
                ' [ キャンセル ] ボタンが押された場合
                MsgBox "ファイルのオープンがキャンセルされました。", vbExclamation
            End If
        End With
    
    End Sub
    
    ⇒ サンプルマクロ集 へ

    • ファイルダイアログの初期表示画面
    • ファイルダイアログの初期表示画面
    • 複数のファイルを選択
    • 複数のファイルを選択するには Shift または Ctrl キーを押した状態でファイルをクリックします。 この例では Shift キーを押した状態でファイルをクリックしています。 複数のファイルを選択
    • [ OK ] ボタンを押した場合
    • 選択した2つのファイルを開いた後、メッセージを表示します。  [ OK ] ボタン押下
    • [ キャンセル ] ボタンまたは右上の [ × ] を押した場合
    •  [ キャンセル ] ボタン押下

  • 『ファイルを保存する』(msoFileDialogSaveAs)使用例
  • ファイルダイアログオブジェクトでファイルを保存する例です。 ファイル保存のため、AllowMultiSelect プロパティや Filters プロパティの設定は不要です。 保存先ファイルを指定して [ OK ] ボタンを押すと、ファイルを保存した後、そのファイルパスをメッセージボックスに表示します。
    『ファイルを保存する』はアクティブワークブックが保存の対象となります。Excute メソッドを実行する前までに、保存対象のワークブックをアクティブにしておいてください。
    Sub sample_ef014_04()
    
        With Application.FileDialog(msoFileDialogSaveAs)
            '初期表示フォルダの設定
            .InitialFileName = "C:\Users\Guest\test\"
    
            If .Show = -1 Then
                ' [ OK ] ボタンが押された場合
                'ファイルの保存実行
                .Execute
    
                MsgBox "以下のファイルに保存されました。" & _
                        vbLf & .SelectedItems(1), vbInformation
            Else
                ' [ キャンセル ] ボタンが押された場合
                MsgBox "ファイルの保存がキャンセルされました。", vbExclamation
            End If
        End With
    
    End Sub
    

    • ファイルダイアログの初期表示画面
    • ファイルダイアログの初期表示画面
    • 保存するファイル名とファイルの種類を指定
    • ここでは、このサンプルマクロが組み込まれたワークブックを保存するので、ファイルの種類をマクロ有効ブック(*.xlsm)にします。 保存するファイル名とファイルの種類を指定
    • [ OK ] ボタンを押した場合
    •  [ OK ] ボタン押下 指定したファイル名で保存されました。 指定したファイル名で保存された様子
    • [ キャンセル ] ボタンまたは右上の [ × ] を押した場合
    •  [ キャンセル ] ボタン押下

カテゴリ内ページ
Excel VBA 〜 総目次 〜
- 2.関数リファレンス
--- (1)-a.InputBox関数
--- (1)-b.InputBoxメソッド
--- (1)-c.MsgBox関数
--- (1)-d.FileDialogオブジェクト@
--- (1)-e.FileDialogオブジェクトA
--- (1)-f.FileDialogオブジェクトB



Page
Top